标题:
柱支撑的索桁结构特征值屈曲的疑问
[打印本页]
作者:
gangdu12345
时间:
2010-1-3 12:31
标题:
柱支撑的索桁结构特征值屈曲的疑问
各位高手，小弟最近在做一柱支撑的索桁结构的屈曲特征值分析，用不断改变外荷载的方式是屈曲特征值变为一 ，可却在计算中无法实现 ，请问大家有没好的办法解决 谢谢了
命令流如下
finish
/clear
/prep7
! 上下部索材料属性
mp,ex,1,1.9e11
mp,dens,1,6.55e3
mp,gxy,1,7.72e10
mp,prxy,1,0.333
mp,alpx,1,1.2e-5
mp,reft,1,0
! 中部杆件材料属性
mp,ex,2,2.6e11
mp,dens,2,6.55e3
mp,gxy,2,7.72e10
mp,prxy,2,0.333
mp,alpx,2,1.2e-5
mp,reft,2,0
! 下部柱属性
mp,ex,3,2.06e11
mp,dens,3,7.85e3
mp,gxy,3,7.72e10
mp,prxy,3,0.333
mp,alpx,3,1.2e-5
mp,reft,3,0
!-------------------60*42
length=60 !------------------长向跨度
kuan=42 !------------------短向跨度
l=2 !------------------长向单元尺寸
k=3 !------------------短向单元尺寸
ls=length/l !------------------长向单元数
ks=kuan/k !------------------短向单元数
b1=4.1 !------------------下弦系数1
b2=5.3 !------------------上弦系数1
a1=4*b1/(length*length) !------------------下弦系数2
a2=4*b2/(length*length) !------------------ 上弦系数2
!------------------构件截面
D11=100E-3
D12=0
D21=80E-3
D22=0
D31=120E-3
D32=0
D41=30E-3
D42=0
D51=1000E-3
D52=30E-3
D61=200E-3
D62=30E-3
D71=30E-3
D72=0
!-------------------创建关键点
*do,i,1,ls+1
k,i,-length/2+(i-1)*l,-kuan,-b1+a1*(-length/2+(i-1)*l)*(-length/2+(i-1)*l)
*enddo
*do,i,1,ls-1
k,ls+1+i,-length/2+i*l,-kuan,b2-a2*(-length/2+i*l)*(-length/2+i*l)
*enddo
k,ls*2+1,-length/2,-kuan,-15
k,ls*2+2,length/2,-kuan,-15
k,ls*2+3,-length/2-10,-kuan,-15
k,ls*2+4,length/2+10,-kuan,-15
ksel,all
kgen,ks+1,1,ls*2+4,,,k,,ls*2+4
!-------------------创建下弦索 1
*do,i,1,ls
*do,j,1,ks+1
l,i+(j-1)*(2*ls+4),i+1+(j-1)*(2*ls+4)
*enddo
*enddo
et,1,link8
AREA1=3.14*D11*D11/4
R,1,AREA1,1/100
TYPE,1
MAT,1
REAL,1
lsel,s,line,,1,ls*(ks+1)
lesize,all,,,1
latt,1,1,1
lmesh,all
!-------------------创建上弦索 2
*do,i,ls+2,2*ls-1
*do,j,1,ks+1
l,i+(j-1)*(2*ls+4),i+1+(j-1)*(2*ls+4)
*enddo
*enddo
*do,j,1,ks+1
l,1+(j-1)*(2*ls+4),ls+2+(j-1)*(2*ls+4)
l,2*ls+(j-1)*(2*ls+4),ls+1+(j-1)*(2*ls+4)
*enddo
AREA2=3.14*D21*D21/4
R,2,AREA2,1/100
TYPE,1
MAT,1
REAL,2
lsel,s,line,,ls*(ks+1)+1,ls*(ks+1)*2
lesize,all,,,1
latt,1,2,1
lmesh,all
!-------------------创建斜拉索 3
*do,j,1,ks+1
l,1+(j-1)*(2*ls+4),2*ls+3+(j-1)*(2*ls+4)
l,ls+1+(j-1)*(2*ls+4),2*ls+4+(j-1)*(2*ls+4)
*enddo
AREA3=3.14*D31*D31/4
R,3,AREA3
TYPE,1
MAT,1
REAL,3
lsel,s,line,,ls*(ks+1)*2+1,ls*(ks+1)*2+(ks+1)*2
lesize,all,,,1
latt,1,3,1
lmesh,all
!-------------------创建竖杆 4
*do,i,1,ls-1
*do,j,1,ks+1
l,i+1+(j-1)*(2*ls+4),i+1+ls+(j-1)*(2*ls+4)
*enddo
*enddo
et,2,link8
AREA4=3.14*D41*D41/4
R,4,AREA4
TYPE,2
MAT,2
REAL,4
lsel,s,line,,ls*(ks+1)*2+(ks+1)*2+1,ls*(ks+1)*2+(ks+1)*2+(ls-1)*(ks+1)
lesize,all,,,1
latt,2,4,2
lmesh,all
!-------------------创建下部柱 5
*do,j,1,ks+1
l,1+(j-1)*(2*ls+4),ls*2+1+(j-1)*(2*ls+4)
l,ls+1+(j-1)*(2*ls+4),2*ls+2+(j-1)*(2*ls+4)
*enddo
et,3,beam188
R,5
TYPE,3
MAT,3
REAL,5
sectype,5,beam,ctube
secdata,D51/2-D52,D51/2,16
secnum,5
lsel,s,line,,ls*(ks+1)*2+(ks+1)*2+(ls-1)*(ks+1)+1,ls*(ks+1)*2+(ks+1)*2+(ls-1)*(ks+1)+(ks+1)*2
lesize,all,,,15
latt,3,5,3
lmesh,all
! 横向支撑类型一 6
*do,i,1,ks
l,1+(2*ls+4)*(i-1),1+(2*ls+4)*i
l,ls+1+(2*ls+4)*(i-1),ls+1+(2*ls+4)*i
*enddo
R,6
TYPE,3
MAT,3
REAL,6
sectype,6,beam,ctube
secdata,D61/2-D62,D61/2,16
secnum,6
b6=ls*(ks+1)*2+(ks+1)*2+(ls-1)*(ks+1)+(ks+1)*2+1
c6=b6+ks*2-1
lsel,s,line,,b6,c6
lesize,all,,,15
latt,3,6,3
lmesh,all
*get,znum6,line,,count
! 横向支撑类型二 7
*do,i,1,ks
*do,j,2,ls
l,j+(2*ls+4)*(i-1),j+(2*ls+4)*i
l,ls+j+(2*ls+4)*(i-1),ls+j+(2*ls+4)*i
*enddo
*enddo
AREA7=3.14*D71*D71/4
R,7,AREA7
TYPE,2
MAT,2
REAL,7
secnum,7
b7=c6+1
c7=b7+ks*(ls-1)*2-1
lsel,s,line,,b7,c7
lesize,all,,,1
latt,2,7,2
lmesh,all
! 横向支撑类型三 8
*do,i,1,ks
*do,j,2,ls
l,j+(2*ls+4)*(i-1),ls+j+(2*ls+4)*i
l,ls+j+(2*ls+4)*(i-1),j+(2*ls+4)*i
*enddo
*enddo
AREA8=3.14*D71*D71/4
R,8,AREA8
TYPE,2
MAT,2
REAL,8
secnum,8
b8=c7+1
c8=b8+ks*(ls-1)*2-1
lsel,s,line,,b8,c8
lesize,all,,,1
latt,2,8,2
lmesh,all
*do,i,1,ks+1
dk,61+(i-1)*(2*ls+4),UX
dk,61+(i-1)*(2*ls+4),UY
dk,61+(i-1)*(2*ls+4),UZ
dk,62+(i-1)*(2*ls+4),UX
dk,62+(i-1)*(2*ls+4),UY
dk,62+(i-1)*(2*ls+4),UZ
dk,63+(i-1)*(2*ls+4),UX
dk,63+(i-1)*(2*ls+4),UY
dk,63+(i-1)*(2*ls+4),UZ
dk,64+(i-1)*(2*ls+4),UX
dk,64+(i-1)*(2*ls+4),UY
dk,64+(i-1)*(2*ls+4),UZ
*enddo
allsel,all
acel,,,9.8
allsel,all
force1 =6000000
force2 =4000000
r1 = 0.003
r2 = 0.002
rmodif,1,2,r1
rmodif,2,2,r2
allsel,all
acel,,,9.8
/SOL
ANTYPE,0
NLGEOM,1
AUTOTS,1
LNSRCH,1
SSTIF,ON
SOLVE
/post1
etable,zl1,smisc,1
etable,yb1,lepel,1
etable,zyl1,ls,1
epsilun1 = 0
epsilun2 = 0
inforce1 = 0
inforce2 = 0
error = 1000
FINISH
*DO,i,1,40
/prep7
out = 1
*get,newforce1,etab,1,elem,218
*get,newforce2,etab,1,elem,653
*if,abs(newforce1-force1),ge,error,then
temp1 = r1
newr1 = r1-(newforce1-force1)/((newforce1-inforce1)/(r1-epsilun1))
r1= newr1
epsilun1= temp1
inforce1 = newforce1
out = 0
rmodif,1,2,r1
*endif
*if,abs(newforce2-force2),ge,error,then
temp2 = r2
newr2 = r2-(newforce2-force2)/((newforce2-inforce2)/(r2-epsilun2))
r2= newr2
epsilun2= temp2
inforce2 = newforce2
out = 0
rmodif,2,2,r2
*endif
/post1
!upcoord,0.1,on
*cfopen,E:\ansys\paper\60sh\sh,txt,,APPEND
*vwrite,r1,r2
(f10.8,f10.8)
*cfclos
*if,out,eq,1,then
*exit
*endif
/solu
ANTYPE,0
NLGEOM,1
AUTOTS,1
LNSRCH,1
SSTIF,ON
SOLVE
/post1
ETABLE,REFL
allsel
*enddo
*get,rr1,etab,2,elem,218
*get,rr2,etab,2,elem,653
finish
/prep7
upcoord,1,on
allsel,all
acel,,,9.8
rmodif,1,2,rr1
rmodif,2,2,rr2
nsel,s,loc,z,0.1,20
*get,node11,node,,count
err=1/10
pmodi=1.0
*dowhile,err
finish
/solu
allsel,all
acel,,,9.8
fkdele,all,all
fan=1.0
per=180
zq=length*kuan*per*9.8*fan
nsel,r,loc,x,-length/2+0.1,length/2-0.1
f,all,fz,-zq*pmodi/node11
allsel,all
FINISH
/SOLU
ANTYPE,STATIC
NLGEOM,off
PSTRES,ON
sstif,on
outres,all,all
solve
FINISH
/solu
antype,1
bucopt,lanb,1
solve
*get,freq1,mode,1,freq
*if,abs(freq1-1),le,err,then
*exit
*else
pmodi=pmodi*freq1
*endif
*enddo
finish
/post1
set,list
欢迎光临 中华钢结构论坛 China Structure Forum (http://bbs.okok.org/)
Powered by Discuz! 5.0.0
