中华钢结构论坛 China Structure Forum

标题: APDL索膜找形-程序纠错 [打印本页]

作者: LEEQING 时间: 2010-3-23 11:08 标题: APDL索膜找形-程序纠错

本人刚接触索寞结构及APDL找形，最近尝试对在找形论文中经常出现的一例子进行找形，进过反复调试，还是有很多错误，现求助于索膜结构中的高手们，忘不吝赐教，你的每一句话，也许对我都是莫大的帮助.....
!马鞍形膜面找形分析
!鞍形膜面找形2010/3/26
finish
/clear
/prep7
EM1=1.6E11       !索的弹性模量
A1=49/10000       !索的面积
ISTRAN=0.999    !索的应变
EM2=8e8/100000    !膜的虚拟弹性模量
H=2             !节点提升高度
T=1/1000          !膜厚
BOS=0.3          !泊松比
SIG0=3000       !膜的预应力
F=30000          !索的预应力
REF=1.0          !热膨胀系数
DETT=-(1-BOS)*SIG0/(EM2*REF) !降低温度
ET,1,LINK10
ET,2,SHELL41
MP,EX,1,EM1
MP,PRXY,1,BOS
MP,EX,2,EM2
MP,PRXY,2,BOS
MP,ALPX,2,REF
R,1,A1,ISTRAN
R,2,T
K,1,-8,0,0$K,2,8,0,0
K,3,0,8,0$K,4,0,-8,0
L,1,4$L,4,2
L,2,3$L,3,1
A,1,4,2,3 !
LATT,1,1,1
AATT,2,2,2
DK,1,UX,,,,,UY,UZ    !在关键点上定义约束条件。
DK,2,UX,,,,,UY,UZ
DK,3,UX,,,,,UY,UZ
DK,4,UX,,,,,UY,UZ
DK,1,UZ,H
DK,2,UZ,H
DK,3,UZ,-H
DK,4,UZ,-H
lesize,all,,,20
lsel,all
ASEL,ALL
mshape,1          !指定单元为三角形单元
mshkey,1          !指定映射网格划分
amesh,all
TREF,0
ASEL,ALL
BFA,ALL,TEMP,DETT !温度荷载
!第一次找形分析
/solu             !保存模型及求解数据
antype,0          !申明分析类型。0表示静力分析
nlgeom,on          !打开大变形
sstif,on          !打开应力刚度选项
nsubst,15          !子步数
outres,all,all
KBC,0
time,1
solve
finish
!有形.............
!更新坐标
/prep7
upcoord,1    !更新所有节点坐标
finish
!多次迭代
*do,i,1,5
/prep7
EM1=1.6E11 !索的真实弹性模量
EM2=8E8    !膜的真实弹性模量
MP,EX,1,EM1
MP,EX,2,EM2
F=2E4
A1=49/10000
ISTRAN=F/A1*EM1  !索的应变量
R,1,A1,ISTRAN
R,2,T
DETT=-(1-BOS)*SIG0/(EM2*REF)
/solu
DK,1,UX,,,,,UY,UZ    !在关键点上定义约束条件。
DK,2,UX,,,,,UY,UZ
DK,3,UX,,,,,UY,UZ
DK,4,UX,,,,,UY,UZ
TREF,0             !参考温度0°
BFA,ALL,TEMP,DETT
ASEL,ALL
solve
finish
/prep7
upcoord,1
finish
*enddo

附件: 101file002.jpg (2010-3-23 11:08, 46.29 K) / 下载次数 2
http://bbs.okok.org/attachment.php?aid=121154

作者: LEEQING 时间: 2010-3-26 10:44 标题: APDL索膜找形-程序纠错

无人问津啊，期待有人指点下啊
论坛毕竟不是百科全书，耐心等待，也许会有答案

作者: xxqxxq2002 时间: 2010-3-27 15:15

EM2=8e8/100000 !膜的虚拟弹性模量
-----------------------------------------------

膜的虚拟弹性模量降低太多了，降低100-1000倍比较合适，索的弹性摸量也要降低的，楼主可以试试

作者: LEEQING 时间: 2010-3-28 10:10

索的模量降低似乎没有影响，因为前面应变给的很大（0.99），事实上，我改过索的模量，影响不是很大。
另外，膜的模量我改到过100-1000（书上都这么说），最后也没有成功。我之所以改到100000，是因为有些论文上说降温幅度DETT在-0.1°~-1°比较合适。还是没有成功，希望多些人帮忙改改......

作者: xxqxxq2002 时间: 2010-3-30 20:50

楼主的模型有点问题，第一好像忘记了生成边界索单元，第二，有些数据可能搞错了单位，比如，SIG0=3000       !膜的预应力，其实应该为3000000才符合实际，我对楼主的命令稍微修改了，效果还不错,就是不知道怎么发送图片。晕死。后半部分楼主自己完善了。



  finish
/clear
/prep7
EM1=1.6E8       !索的弹性模量
A1=0.0002  !索的面积

EM2=8e8/1000    !膜的虚拟弹性模量
H=2       !节点提升高度
T=1/1000          !膜厚
BOS=0.0          !泊松比
SIG0=3e6       !膜的预应力    !SIG0=3000    (施加的力太小了，注意单位）
F=30000          !索的预应力
ISTRAN=F/(A1*EM1)  !索的应变

REF=1.0          !热膨胀系数
DETT=-SIG0/(EM2*REF) !降低温度
ET,1,LINK10
ET,2,SHELL41
MP,EX,1,EM1
MP,PRXY,1,BOS
MP,EX,2,EM2
MP,PRXY,2,BOS
MP,ALPX,2,REF
R,1,A1,ISTRAN
R,2,T
K,1,-8,0,0$K,2,8,0,0
K,3,0,8,0$K,4,0,-8,0
L,1,4$L,4,2
L,2,3$L,3,1
A,1,4,2,3 !
LATT,1,1,1
AATT,2,2,2
DK,1,UX,,,,,UY,UZ    !在关键点上定义约束条件。
DK,2,UX,,,,,UY,UZ
DK,3,UX,,,,,UY,UZ
DK,4,UX,,,,,UY,UZ
DK,1,UZ,H
DK,2,UZ,H
DK,3,UZ,-H
DK,4,UZ,-H
lesize,all,,,20
lsel,all
ASEL,ALL
mshape,1          !指定单元为三角形单元
mshkey,1          !指定映射网格划分
amesh,all
lmesh,all
TREF,0
ASEL,ALL
BFA,ALL,TEMP,DETT !温度荷载
!第一次找形分析
/solu             !保存模型及求解数据
antype,0          !申明分析类型。0表示静力分析
nlgeom,on          !打开大变形
sstif,on          !打开应力刚度选项
nsubst,15          !子步数
outres,all,all
KBC,0
time,1
solve
finish

作者: LEEQING 时间: 2010-4-2 10:21 标题: APDL索膜找形-程序纠错

1、如何生成索？
2、楼上改完后，初次找形的结果是不错了，为何我在多次迭代求解之后，反而不及第一次找形后的应力均匀？
3、楼上仁兄如果方便，请贴出后面迭代部分....

作者: lianrenweiman 时间: 2010-5-18 21:14

在索膜结构找形中，索膜的弹性模量设置，边界设置（刚性边界或者柔性边界），对于最终的找形结果影响很大。出现问题的时候，多对上述参数进行调整，同时最好用另外的软件进行验证对比。
索膜找形是个比较复杂的过程，慢慢试试就好了

欢迎光临中华钢结构论坛 China Structure Forum (http://bbs.okok.org/)